#INCLUDE DEFINES.H

PARAMETER cAppName, cDbName, cDbPath
STORE PARAMETERS() TO lnParams
STORE .F. TO llError, lRelease
ON ERROR llError = .T.
IF TYPE('oSQLSrvr') <> 'O'
	osqlsrvr = createobject('sqlole.sqlserver')
	IF TYPE('oSQLSrvr') <> 'O'
		WAIT WINDOW "Unable to create SQL Server OLE object." TIME 2.0
		RELEASE osqlSrvr
		ON ERROR
		RETURN
	ENDIF
	WAIT WINDOW NOWAIT "Connecting to SQL Server..."
	ret =osqlsrvr.connect(_SQL_SERVER, _SQL_LOGIN, _SQL_PASSWORD)
	IF llError
		WAIT WINDOW MESS() TIME 2.0
		RELEASE osqlSrvr
		ON ERROR
		RETURN
	ENDIF
	lRelease = .T.
ENDIF
oDb = osqlsrvr.databases(cDbName)
IF TYPE('oDb') <> 'O' OR llError
	WAIT WINDOW "Unable to create SQL Server Database object." TIME 2.0
	RELEASE osqlSrvr, oDb
	ON ERROR
	RETURN
ENDIF
eH = FCREATE(_LOG_PATH + "\" + cAppName + ' Sprocs Error.log')
USE (IIF(TYPE('cDbpath') <> 'C', _SQL_PATH, cDbPath) + "\" + cAppName + "_SPROCS")
lcCount	= ALLT(STR(RECCOUNT()))
SET MESSAGE TO 'Generating...'
lnRecCount = 0
SCAN FOR !EMPTY(ALLTRIM(Name))
	lnRecCount = lnRecCount + 1
	cSpName = "dbo." + ALLTRIM(Name)
	h = FCREATE('C:\Temp\' + ALLTRIM(Name) + '.sql')
	WAIT WINDOW NOWAIT "Generating for " + cSpName + "..." + ;
				ALLT(STR(lnRecCount)) + "/" + lcCount
	= FPUTS(h, 'PRINT "Creating ' + ALLTRIM(Name) + '..."')
	= FPUTS(h, 'GO')
	= FPUTS(h, '')
	= FPUTS(h, oDb.StoredProcedures(cSpName).Script(_FULLSP_SCRIPT))
	IF llError
		llError = .F.
		= FPUTS(eH, cSpName + ":" + MESS())
		= FFLUSH(eH)
	ENDIF
	= FFLUSH(h)
	= FCLOSE(h)
ENDSCAN
= FCLOSE(eH)
USE
SET MESSAGE TO
IF lRelease
	cErrorFile	= _LOG_PATH + "\" + cAppName + ' Sprocs Error.log'
	MODI FILE &cErrorFile
	WAIT WINDOW NOWAIT "Releasing Resources..."
	oSqlSrvr.Disconnect
	osqlsrvr.Close
	RELEASE ALL
	WAIT CLEAR
	ON ERROR
	RETURN
ENDIF